#!/usr/bin/perl

#
# Alex Linke <alex@use-strict.de>
#

# The filter's license is available here:
# 	http://www.use-strict.de/files/software/LICENSE.txt

# There's no warranty at all - Use at own risk!

use strict;

my $VERSION = '0.04';

usage() unless ( @ARGV == 1 ); 
usage(0) if ( $ARGV[0] =~ /^-(h|-help)$/ );

my $Fin = $ARGV[0];

# handle STDIN (piped data)
$Fin = "/dev/stdin" if ( $Fin eq '-' );

my ( @finalStates, $result );

open FH, "$Fin" or die "Error opening '$Fin': '$!'\n";

my $lastState = "";
# extract states
foreach( <FH> ) {
    chomp;
    
    next unless ( s/^(f?s\d+):// || $lastState );

    my $originState;

    # already found a state in the last loop that isn't finished yet?
    if ( $lastState eq "" ) {
        $originState = $1;
    }
    else {
        $originState = $lastState;
    }
    
    # is another loop needed for _this_ state?
    if ( /,$/ ) {
        $lastState = $originState;
    }
    else {
        $lastState = "";
    }

    while( s/^(?:\s+)<?([^\s>]+)>?\s+-\>\s+(f?s\d+)[\.,]?// ) {
        my ( $trigger, $destState ) = ( $1, $2 );
        $result .= "\t$originState -> $destState [label=\"$trigger\"];\n";
    }

    # remeber if originState is final:
    push @finalStates, $originState if ( $originState =~ /^f/ );
}

# final states -> doublecircle
$result .= "\t$_ [shape=\"doublecircle\"];\n" foreach @finalStates;


# print results or notify
unless ( $result =~ /^$/ ) {
    print  <<DOT
# created by xfst2dot.pl v$VERSION

digraph foo {
        node[shape=circle,label=""];
        orientation="land";

$result
}
DOT
}
else {
    print STDERR "No results generated. " .
        "Did you feed me \"print net\" output?\n";
        exit 1;
}

sub usage {
    print "usage: $0 [print-net-file|STDIN(-)]\n";
    exit $_[0]||1;
}